| -----------------------------------------------------
| irc client
| -----------------------------------------------------
include netclient.f

: freenode { server: 140.211.166.4 6667 } ;
: /join vector ;    : say vector ;
: /me vector ;      : /nick vector ;
: irc.ui vector ;   : in vector ;
: irc { ' irc.ui is ui } ;

create ^Acrlf 1 1, 13 1, 10 1,
: ^A ^Acrlf 1 net.write ;
: CR ^Acrlf 1+ 2 net.write ; 
: ^ACR ^Acrlf 3 net.write ;

loc:
 : channel s" PRIVMSG #dexos :" net.write ;
 : send net.write lnparse net.write ;

 loc:
  variable off
  : mpad here 2048 + ;
  : process drop mpad off @ type cr 0 off ! ;
  : copy dup 32 <if drop 32 then mpad off @ + c! 1 off +! ;
  :: net.read dup 10 =if process ;; then copy ;
 ;loc alias update 

 : show? net? 1 =if update then ;
 :: repeat key? 1 =if ;then show? again ; is irc.ui

 :: lnparse channel net.write CR ; is say 
 :: s" JOIN " send CR ; is /join
 :: channel net.write ^A s" ACTION " send ^ACR ; is /me
 :: s" NICK " send CR ; is /nick
;loc

freenode

" USER crcx charles childers :irc.f" net.write CR
/nick crcx
/join #dexos

irc reset
: chat { ' say is how } ;
reset